Cannonball Blitz for the Apple 2 driving me crazy

I remembered this old Apple 2 game called Cannonball Blitz and how impossible it was.



So why not try to fiddle with the mame debugger to get some extra lives. The game gives you a measly 3 lives.

./mame64 apple2e canbbltz -debug


It draws the number of lives in the upper left corner of the graphics screen, so let's set a watchpoint for address $2000.

wpset $2000,1,w

let it run and then do

history

and if you read the list of instructions you'll see a

lda $6f12



and if you open a memory window and change memory location $6f12 to something else, say $7F, you'll have 127 lives.

I tried $FF for 255 lives, but the code does a

9c01 dec $6f12
9c04 bmi $9c17

so anything larger than 127 seems to trigger the branch.

Setting up watchpoints on $6f12 with wpset $6f12,1,rw leads me to the code that initializes the number of lives:

868b lda #$02
868d sta $6f12






So let's just open up a memory window to 868b:



and change that 02 to a 7F:




So now at least I can keep trying to get past level 2... it only displays one character for the number of lives, so you'll only see the lower nibble of the number of lives.

Hey! I finally beat level 2 for the first time ever!



On to level 3!




Finally finished level 3!

I had to use the save state feature of mame, LEFT SHIFT+F7 and then 1 to save state into position 1, F7 to load state.

I saved it right at this spot and must've loaded it about 50 times.



You have to pause and then run under at two spots.



Seriously hard...but finished that level.




More silly fun, let's find where the score is stored.



In the mame debugger, we'll use the f command

So I didn't know exactly how to use it, so I typed "help memory".



One nasty side effect is that reading the memory where the soft switches that control the screen display will put you into text mode, which is easily fixed by restoring the save state with F7 (you did save a state, didn't you?)

So first I tried converting 32760 into hexadecimal for $7ff8, but I couldn't find that in memory, so I decided it must be stored as BCD, for 03 27 60.



It stores it in 9153 and 9156, 9153 seems to be a temporary shadow, 9156 seems to be the "real score".

Setting to FFFFFF gives you this crazy score.

Fiddling with coco2 graphics

It's interesting to figure out how the coco2 does its graphics.

I got a book on Extended Color Basic to get me started. It's a pretty cool tutorial.

http://www.colorcomputerarchive.com/coco/Documents/Manuals/Hardware/Getting%20Started%20With%20Extended%20Color%20Basic%20(Tandy).pdf


I wrote a little basic program to investigate how it works.


Some stuff I learned:

For some reason, mame gets the shift key stuck and I end up having to hold down SHIFT to invert the shift. I don't understand it exactly.
edit: Actually, I found that SHIFT+0 toggles CAPS lock.

The color basic EDIT command drives me completely insane, especially when the SHIFT key is doing strange things. I've gone to editing programs in a text editor then using paste to paste them into mame (UI Paste seems to be bound to SCROLL LOCK+SHIFT which is less than ideal, I think I'll change it).


INSTR matches an empty string at position 1, I would think that INSTR shouldn't match the empty string at all, giving 0.

You can change the PMODE for the graphics mode, but the screen display doesn't change until you execute a SCREEN command.

If you're in graphics mode and you PRINT anything to the screen, it reverts to text mode and sets the 0 background colors, basically executing a SCREEN 0,0.

Coco 2 graphics memory starts at 0xD00 or 14*256. With Disk Basic it starts at 0xD00, cassette basic starts graphics at 0x600. I wanted to poke into memory and see what happens.

The coordinates for the graphics depend upon the PMODE, and will adjust for the screen mode, where 0,0 is the upper left, and 255,191 is the lower right.




So my program just pokes some random data into the start of graphics memory page 1.

S will toggle to the alternate color set (either 0 or 1)
G will toggle from text to graphics (either 0 text or 1 graphics)
01234 will set the PMODE to that number
QWERTYUI will set the color to 01234567 and draw a rectangle
C will clear the screen
A will draw a line from 0,0 to 255,191 in a random color
Z will print a line of text automatically returning you to text mode

100 SCREEN 1,1
110 PMODE 4,1
111 S = 1
112 G = 1
115 FOR I=0 TO 31
120 POKE 14*256+I,RND(0)*255
130 A$ = INKEY$
132 IF A$<>"" THEN IF ASC(A$)<=ASC("4") AND ASC(A$)>=ASC("0") THEN PMODE ASC(A$)-ASC("0"),1:SCREEN 1,S

133 IF A$="A" THEN COLOR RND(0)*7:LINE(0,0)-(255,191),PSET
134 IF A$="C" THEN PCLS
135 IF A$<>"" THEN B$="QWERTYUI":IF INSTR(B$,A$)<> 0 THEN C=INSTR(B$,A$)-1:COLOR C:LINE(256/2-10,192/2-10)-(256/2+10,192/2+10),PSET,B:SCREEN G,S

136 IF A$="S" THEN S=1-S:SCREEN G,S
137 IF A$="G" THEN G=1-G:SCREEN G,S
138 IF A$="Z" THEN PRINT "PRINTING WILL RETURN TO THE TEXT MODE"

140 NEXT

200 GOTO 115

starts up in PMODE 4,1 (256x192 2 colors), note that going to graphics mode doesn't clear the screen



same screen in PMODE 3,1 (128x192 4 colors)


same screen in PMODE 0,1 (128x96, 2 colors)


now if you type C to clear the screen in PMODE 0,1 it will only clear what is visible, and hitting A to draw a diagonal line across:



then switching to PMODE 4,1 gives you:

Coco3 easter egg

I'm having fun fiddling with the coco emulation and I read about the easter egg in the coco3. Hold CTRL+ALT at bootup and you get a picture of "the coco 3".


http://www.cocopedia.com/wiki/index.php/CoCo3_Easter_Egg

So I'm late to the coco party (I'm sure all coco owners know about it).


Launch mame with

./mame64 coco3

and hold down CTRL+ALT before the mame info screen, and hit space to continue past the info screen:



You have to hold CTRL+ALT before the info screen comes up, because pressing CTRL or ALT will send you past the screen.

Olympic Decathlon for the Coco

Have you ever played a game that is just incredibly infuriating but you want to beat it so you keep on playing?

I came across this Olympic Decathlon game for the tandy coco and it is most difficult because it doesn't let you continue unless you "qualify" for each event. If you don't measure up, you have to start over again.

It's written by L. Curtis Boyle and you can find it at his website.

http://www.lcurtisboyle.com/nitros9/olympicdecathlon.html




It starts up with a blank screen so you have to hit "C" for continue.






and hit C to continue past the rings screen.














and it's written in BASIC so you can see how it was made. Pretty clever. I want to fix it so I can see all of the events. I can't keep doing the 100 meter dash.




So to get printing to work with mame, use the -printout option like so:

./mame64 coco2 -flop1 curtisboyle.zip -printout printout.txt

and do an LLIST command: (and be prepared to wait a few minutes to get the cursor back since it takes a while)



and you get the file, but first it needs to be cleaned up, there's an FF at the beginning and ^M at the end of every line.

To fix the printout file for linux, use this sed command:

sed -i -e 's/\r/\n/g' printout.txt

that changes \r return characters to \n newline characters.

0 CLEAR600,&H7FE6:PCLEAR8:DIMCC$(47):FOR A=1 TO 47:READ LL$,CC$(A):NEXT:FOR A=&H7FE6 TO &H7FFE:READA$:POKEA,VAL("&H"+A$):NEXT
1 POKE65495,0:PMODE4:SCREEN1,1:PMODE3:PCLS3:PMODE4
2 IF INKEY$=""THEN2
3 CLS:INPUT"<1> START THE GAMES          OR <2> SEE THE DEMO";Q
4 PMODE4,5:PCLS:SCREEN1,1:FORA=80 TO 190STEP50:FORB=30 TO 35STEP5:CIRCLE(A,50),B:NEXT:PAINT(A,82),1,1:PAINT(A-32,50),1,1:NEXT
5 CIRCLE(105,75),30:CIRCLE(105,75),35:PAINT(98,107),1,1:CIRCLE(155,75),30:CIRCLE(155,75),35:PAINT(155,107),1,1:PAINT(123,75),1,1:PAINT(73,75),1,1:PAINT(137,75),1,1:PAINT(187,75),1,1
6 PAINT(105,42),1,1:PAINT(155,42),1,1:PAINT(140,45),1,1:PAINT(120,45),1,1:PAINT(125,90),1,1:PAINT(130,55),1,1
7 DIM G(1,17),H(1,17),I(1,17),T(1,12),J(1,17),K(1,17),L(1,18),M(1,17)
8 PMODE4,1:PCLS:DRAW"BM19,1UFGHED3NL5G10NH2E5D5L2":GET(0,0)-(20,18),L,G
9 PCLS:DRAW"BM7,10NR2D5R5G2NL2E2R3GHEF":GET(0,0)-(20,17),M,G
10 PCLS:DRAW"BM15,5UFGHED3F4NE3H4LL4ND2R4D3F6NR2H6G3H3G"
11 GET(3,0)-(23,17),G,G
12 PCLS:DRAW"BM15,5UFGHED3G3NF2E3D3NE3D3L3ND2R3D3R2"
13 GET(0,0)-(20,17),H,G
14 PCLS:DRAW"BM15,5UFGHED3GNFEDNFD4G3ND2E3D5R2"
15 GET(0,0)-(20,17),I,G
16 PCLS:DRAW"BM10,6UFGHED2NF3G5F6E2":GET(0,0)-(20,17),J,G
17 PCLS:DRAW"BM12,3UFGHED2NF3G5L6D2":GET(0,0)-(20,17),K,G
18 PCLS:DRAW"BM7,3R6D2GLD3GHU3LHU2E3F3"
19 POKE178,2:PAINT(9,2),,1
20 GET(4,0)-(13,12),T,G
21 IFQ=1THEN40
22 PMODE4,5
23 LINE(0,180)-(255,180),PSET:POKE178,2:PAINT(0,181),,1
24 A$="T255A"
25 DRAW"BM210,180C1E2U5H2L2U2R23D2L2G2D5F2"
26 FOR A=0 TO 170STEP10:PUT(A,160)-(A+20,177),G,PSET:PUT(A+21,160)-(A+30,172),T,PSET:PUT(A+3,160)-(A+23,177),H,PSET:PUT(A+25,160)-(A+34,172),T,PSET:PUT(A+7,160)-(A+27,177),I,PSET:PUT(A+28,160)-(A+37,172),T,PSET:PLAYA$:NEXT
27 LINE(A+18,160)-(A+27,172),PRESET,BF
28 FOR A=1 TO 4:PCOPYA+4 TO A:NEXT A
29 DRAW"BM62,130S12":AA$="OLYMPIC":GOSUB155:DRAW"BM40,160":AA$="DECATHLON":GOSUB155:DRAW"BM2,6S4":AA$="COPYRIGHT 1984 BY COLORNOVA SOFTWARE":GOSUB155:DRAW"BM2,20":AA$="WRITTEN":GOSUB155
30 DRAW"BM2,30":AA$="BY L.":GOSUB155:DRAW"BM2,40":AA$="CURTIS":GOSUB155:DRAW"BM2,50":AA$="BOYLE":GOSUB155
31 DRAW"S4BM208,169E6F3EF2E4F5":POKE178,2:PAINT(210,168),,1:PMODE4,1:DRAW"BM208,169E2R2E2FE5F3EF3EF4":POKE178,2:PAINT(210,168),,1:COLOR1
32 FORA=1TO460:NEXT:PMODE4,5:SCREEN1,1:FORT=1TO460:NEXTT:PMODE4,1:SCREEN1,1
33 IF INKEY$<>"C"THEN32
34 PMODE4:SCREEN1,1
35 PCLS:DRAW"BM2,8":AA$="WELCOME TO THE OLYMPIC DECATHLON!":GOSUB155:DRAW"BM2,18":AA$="IN THIS EXCITING SIMULATION YOU WILL":GOSUB155:DRAW"BM2,28":AA$="COMPETE IN 1O DIFFERENT EVENTS FROM":GOSUB155:DRAW"BM2,38":AA$="THE GAMES INCLUDING:"
36 GOSUB155
37 DRAW"BM2,48":AA$="1OO METER DASH":GOSUB155:DRAW"BM2,58":AA$="LONG JUMP":GOSUB155:DRAW"BM2,68":AA$="SHOT PUT":GOSUB155:DRAW"BM2,78":AA$="HIGH JUMP":GOSUB155:DRAW"BM2,88":AA$="4OO METERS":GOSUB155:DRAW"BM2,98":AA$="11O METER HURDLES"
38 GOSUB155:DRAW"BM2,108":AA$="DISCUS THROW":GOSUB155:DRAW"BM2,118":AA$="POLE VAULT":GOSUB155:DRAW"BM2,128":AA$="JAVELIN":GOSUB155:DRAW"BM2,138":AA$="15OO METERS":GOSUB155
39 DRAW"BM2,148":AA$="IN ORDER TO CONTINUE IN THE COMPETIT-":GOSUB155:DRAW"BM2,158":AA$="ION, YOU MUST GET A GOOD ENOUGH SCORE":GOSUB155:DRAW"BM2,168":AA$="TO QUALIFY FOR THE NEXT EVENT.":GOSUB155:GOSUB152
40 COLOR1:SCREEN1,1:PCLS:DRAW"BM100,10":AA$="1ST EVENT:":GOSUB155:DRAW"BM42,90S12":AA$="1OO METER":GOSUB155:DRAW"BM90,140":AA$="DASH":GOSUB155:B=80:TI=11.5
41 GOSUB152
42 POKE&H7FE8,&H80:POKE&H7FE7,&H24:PMODE4,1:SCREEN1,1
43 GOSUB154
44 PLAY"T255":DRAW"BM2,20":AA$="LEFT ARROW IS LEFT FOOT FORWARD.":GOSUB155:DRAW"BM2,60":AA$="RIGHT ARROW IS RIGHT FOOT FORWARD.":GOSUB155:DRAW"BM2,100":AA$="START ON LEFT FOOT.":GOSUB155:SOUND100,10
45 A=0:TIMER=0
46 IFS>=B THENT=TIMER:GOTO49ELSEA$=INKEY$:IFA$=CHR$(8)ANDA=0THENA=1:PUT(20,162)-(40,179),G,PSET:PLAY"A":EXEC&H7FE6:S=S+1:GOTO46
47 IFA$=CHR$(9)ANDA=1THENA=0:EXEC&H7FE6:PUT(20,162)-(40,179),H,PSET:PLAY"A":S=S+1:GOTO46
48 GOTO 46
49 FORA=1TO12:PLAY"T12;N=A;":NEXT:LINE(0,0)-(255,179),PRESET,BF:DRAW"BM2,10":GOSUB51:AA$="YOUR TIME WAS"+C$+" SECONDS.":GOSUB155:IF T/40-1.5<ti THENDRAW"BM2,40":AA$="YOU QUALIFIED!!":GOSUB155:GOTO53
50 DRAW"BM2,40":AA$="SORRY, YOU DIDN'T QUALIFY":GOSUB155:SOUND1,20:CLS:INPUT"DO YOU WANT TO QUIT THE GAMES   <Y/N>";A$:IFA$="Y"THENCLS:ENDELSERUN
51 C$=STR$(T/40-1.5):FORQ=1TOLEN(C$):IFMID$(C$,Q,1)="0"THENMID$(C$,Q,1)="O":NEXT ELSE NEXT
52 RETURN
53 GOSUB150:IFB=320THEN102ELSEIFB=1200THEN149
54 PCLS:DRAW"BM100,10S4":AA$="2ND EVENT:":GOSUB155:DRAW"BM80,100S12":AA$="LONG":GOSUB155:DRAW"BM80,150":AA$="JUMP":GOSUB155:GOSUB15255 GOSUB154:DRAW"C1BM2,10":AA$="PRESS THE RIGHT ARROW TO SPEED UP":GOSUB155:DRAW"BM2,40":AA$="PRESS SPACE BAR TO JUMP":GOSUB155:SOUND1,10:S=90
56 C=C+1:IFC>98 THEN61ELSEA$=INKEY$:IFA$=CHR$(9)THENS=S-10:IFS<1THENS=1
57 IFA$=" "THEN62
58 IFP=0THENPUT(20,162)-(40,179),G,PSET ELSE PUT(20,162)-(40,179),H,PSET
59 P=1-P:FORQ=1TOS:NEXT:EXEC&H7FE6:IFC>70THENLINE(247,180)-(255,191),PSET,BF
60 GOTO 56
61 PMODE2,1:PCLS:PMODE4,1:DRAW"BM2,10":AA$="YOU RAN RIGHT INTO THE SAND!":GOSUB155:GOTO50
62 X=50/S:IFX=50THENX=5
63 LINE(20,178)-(40,178),PRESET:Y1=160:Y2=177:FOR A=1TOX:PUT(20,Y1)-(40,Y2),K,PSET:C=C+1:EXEC&H7FE6:PLAY"T255A":Y1=Y1-5:Y2=Y2-5:NEXT:FORA=1TO5:C=C+1:PUT(20,Y1)-(40,Y2),H,PSET:EXEC&H7FE6:PLAY"T255A":NEXT
64 FOR A=1 TO X+2:EXEC&H7FE6:PUT(20,Y1)-(40,Y2),J,PSET:C=C+1:PLAY"T255A":Y1=Y1+5:Y2=Y2+5:NEXT:JD=(3*X+2)/1.8:LINE(0,0)-(255,50),PRESET,BF:DRAW"BM2,10":GOSUB66:AA$="YOUR JUMP WAS"+C$+" METERS LONG.":GOSUB155
65 DRAW"BM2,40":IFVAL(C$)>7.99THENAA$="YOU QUALIFIED!!":GOSUB155:GOSUB150:GOTO68ELSEGOTO50
66 C$=STR$((C-98)/2-(RND(5)/10)):IFVAL(C$)<0THENC$="O"
67 RETURN
68 PCLS:DRAW"BM100,10S4":AA$="3RD EVENT:":GOSUB155:DRAW"BM80,100S12":AA$="SHOT":GOSUB155:DRAW"BM90,150":AA$="PUT":GOSUB155:GOSUB152
69 PCLS:DRAW"BM2,10":AA$="PRESS THE SPACE BAR AS FAST AS YOU":GOSUB155:DRAW"BM2,20":AA$="CAN TO THROW.":GOSUB155:LINE(2,30)-(80,90),PSET,B:LINE(0,180)-(255,180),PSET:POKE178,2:PAINT(0,181),,1
70 A$="BM9,89U20HU10E4NR8U3H3U8E3R10F3D2GDBL2LBR3F3L3DNL3D2L4D3BU12BR5L6D3LLU3G4D4":A1$="BD6BR2D20F5END10NE16GH5U20BR5BU2F2D12GDDGND2E13NF5U2H3U3E2ND3E2ND4R2ND4F2D2D6GND5EU6BL8UE4R4F4D4G4":S1$=A$+A1$
71 A2$="BD10BR2R20NF3E15NF5U2H4U3E2ND3E2ND4R2ND4F2ND7BD2BL8UE4R4F4D4G4D6F2G18L17ND21BU9NU4BD9L6":S2$=A$+A2$:DRAW"C1;XS1$;":SOUND1,1072 FOR A=9 TO 255STEP8:LINE(A,176)-(A,179),PSET:NEXT:DRAW"BM76,165C1":AA$="1O":GOSUB155:DRAW"BM156,165":AA$="2O":GOSUB155:DRAW"BM236,165":AA$="3O":GOSUB155:DRAW"BM110,150":AA$="METERS":GOSUB155
73 A=0:TIMER=0
74 IF INKEY$=" "THENA=A+1
75 IFTIMER>85THEN76ELSE74
76 DRAW"C0;XS1$;C1;XS2$;":FORN=1TO8*A:PSET(N,175):PLAY"T255A":PRESET(N,175):NEXT:PRESET(N,180)
77 LINE(0,0)-(255,90),PRESET,BF:DRAW"BM2,10":GOSUB79:AA$="YOU THREW THE SHOT PUT"+A$+" METERS":GOSUB155:DRAW"BM2,20":IFA>19THENAA$="YOU QUALIFIED!!!":GOSUB155ELSEGOTO50
78 GOSUB150:GOTO81
79 A$=STR$(A):IFA=10 THENA$=" 1O" ELSE IF A=20 THEN A$=" 2O" ELSEIFA=30 THEN A$=" 3O"
80 RETURN
81 PCLS:DRAW"BM100,10S4":AA$="4TH EVENT":GOSUB155:DRAW"BM80,100S12":AA$="HIGH":GOSUB155:DRAW"BM80,150":AA$="JUMP":GOSUB155:GOSUB152
82 PCLS:LINE(0,180)-(255,180),PSET:POKE178,2:PAINT(0,181),,1:COLOR1:LINE(200,175)-(255,180),PSET,B:POKE178,1:PAINT(201,176),,1:COLOR1:LINE(198,169)-(199,180),PSET,B
83 LINE(2,50)-(90,120),PSET,B:LINE(9,60)-(9,100),PSET:LINE(9,100)-(80,100),PSET
84 DRAW"BM2,10":AA$="PRESS RIGHT ARROW TO SPEED UP":GOSUB155:DRAW"BM2,20":AA$="PRESS SPACE BAR FIRST TO STOP RUN-":GOSUB155:DRAW"BM2,30":AA$="NING, AND THE 2ND TIME TO JUMP":GOSUB155
85 S=90:A=0:X=1
86 IFX>178THEN91
87 A$=INKEY$:IFA$=CHR$(9)THENS=S-10:IFS<1THENS=1
88 IFA$=" "THEN92
89 IFA=0THENPUT(X,162)-(X+20,179),G,PSET ELSEPUT(X,162)-(X+20,179),H,PSET
90 A=1-A:FORB=1TOS:NEXT:X=X+4:GOTO86
91 LINE(0,0)-(255,40),PRESET,BF:DRAW"BM2,10":AA$="YOU RAN RIGHT INTO THE BAR!!!":GOSUB155:GOTO50
92 FOR A=.99 TO .75 STEP-.01:CIRCLE(9,100),40,1,1,A,1
93 FORB=1TOS:NEXT:IFINKEY$=" "THEN95
94 NEXT
95 S=((100-S)/10)/2:A=(1-A)*10+(S/2)
96 Y=161:FOR B=1TOS:PUT(X,Y)-(X+20,Y+18),L,PSET:X=X+S:Y=Y-A:NEXT
97 FORB=1TOS:PUT(X,Y)-(X+20,Y+17),M,PSET:X=X+S:Y=Y+A:NEXT
98 FOR A=168 TO 175:IF PPOINT(198,A)<>0 OR PPOINT(199,A)<>0THEN99ELSENEXT:C$=" 1":GOTO100
99 B=(175-A)*.25+1:LINE(0,0)-(255,40),PRESET,BF:DRAW"BM2,10":AA$="YOU JUMPED"+STR$(B)+" METERS":GOSUB155:DRAW"BM2,20":IFB>=2.25THENAA$="YOU QUALIFIED!!!":GOSUB155ELSE50
100 GOSUB150
101 PCLS:DRAW"BM100,10S4":AA$="5TH EVENT":GOSUB155:DRAW"BM100,100S12":AA$="4OO":GOSUB155:DRAW"BM70,150":AA$="METERS":GOSUB155:GOSUB152:B=320:TI=50:GOTO42
102 PCLS:DRAW"BM100,10S4":AA$="6TH EVENT":GOSUB155:DRAW"BM100,100S12":AA$="11O":GOSUB155:DRAW"BM80,130":AA$="METER":GOSUB155:DRAW"BM60,160":AA$="HURDLES":GOSUB155:GOSUB152:GOSUB154:A=0:S=90:B=-3
103 FOR P=0 TO 255STEP64:LINE(P,175)-(P+1,179),PSET,B:NEXT:DRAW"BM2,10":AA$="PRESS THE RIGHT ARROW TO SPEED UP":GOSUB155:DRAW"BM2,40":AA$="PRESS SPACE BAR TO JUMP":GOSUB155:POKE&H7FE7,&H23:POKE&H7FE8,&HE0:SOUND1,10:TIMER=0
104 A$=INKEY$:IFA$=CHR$(9)THENS=S-10:IFS<1THENS=1
105 IFA$=" "THEN110
106 IFA=0THENPUT(20,162)-(40,179),G,PSET ELSEPUT(20,162)-(40,179),H,PSET
107 FORQ=1TOS:NEXT:IFB=0THEN109ELSEIFB/8=INT(B/8) THENLINE(0,0)-(255,40),PRESET,BF:DRAW"BM2,10":AA$="YOU RAN RIGHT INTO A HURDLE!!!":GOSUB155:GOTO50
108 IF(B-4)/8=INT((B-4)/8)THENFORA=0TO256STEP64:LINE(A,175)-(A+1,179),PSET,B
109 LINE(20,175)-(40,179),PRESET,BF:A=1-A:EXEC&H7FE6:B=B+1:IFB>104THENT=TIMER-200:GOTO111ELSE104
110 PUT(20,157)-(40,174),K,PSET:EXEC&H7FE6:FORQ=1TOS*1.5:EXEC&H7FE6:B=B+2:LINE(20,156)-(40,160),PRESET,BF:GOTO106
111 LINE(0,0)-(255,40),PRESET,BF:GOSUB51:DRAW"BM2,10":AA$="YOU RAN THE HURDLES IN"+C$+" SECONDS":GOSUB155:IFVAL(C$)<16THENDRAW"BM2,20":AA$="YOU QUALIFIED!!!":GOSUB155:GOSUB150ELSEGOTO50
112 PCLS:DRAW"BM100,10S4":AA$="7TH EVENT":GOSUB155:DRAW"BM70,100S12":AA$="DISCUS":GOSUB155:DRAW"BM80,150":AA$="THROW":GOSUB155:GOSUB152:PCLS:DRAW"BM2,10":AA$="PRESS THE SPACE BAR TO RELEASE DISC-":GOSUB155
113 DRAW"BM2,20":AA$="US":GOSUB155:S=90:FORA=172 TO 32STEP-10:LINE(20,A)-(255,A),PSET:NEXT:FOR A=175TO35STEP-20:DRAW"BM14,=A;":AA$="5":GOSUB155:NEXT:FORA=165 TO 45STEP-20:DRAW"BM14,=A;":AA$="O":GOSUB155:NEXT
114 B=1:FOR A=165 TO 35STEP-10:DRAW"BM0,=A;":AA$=STR$(INT(B)):MID$(AA$,1,1)="":GOSUB155:B=B+.5:NEXT:S=90
115 X$="BM130,185":DRAWX$+"C1NU10":P=1:GOSUB118:DRAWX$+"C0NU10":DRAWX$+"C1NE10":P=2:GOSUB118:DRAWX$+"C0NE10":DRAWX$+"C1NR10":P=3:GOSUB118:DRAWX$+"C0NR10":DRAWX$+"C1NF10":P=4:GOSUB118:DRAWX$+"C0NF10":DRAWX$+"C1ND10":P=5:GOSUB118:DRAWX$+"C0ND10"
116 DRAWX$+"C1NG10":P=6:GOSUB118:DRAWX$+"C0NG10":DRAWX$+"C1NL10":P=7:GOSUB118:DRAWX$+"C0NL10":DRAWX$+"C1NH10":P=8:GOSUB118:DRAWX$+"C0NH10":S=S-5:IFS<1THENS=1
117 GOTO115
118 FORB=1TOS:NEXT:IFINKEY$=" "THEN119ELSERETURN
119 IFP>2ANDP<8THEN122ELSEA=(100-S)/10:IFP=1THENA=A*3.3 ELSEIFP=8ORP=2THEN A=A*2.8
120 X=130:A=A+RND(5):IFP=8THENQ=-1ELSEIFP=2THENQ=1ELSEQ=0
121 FORB=1TOA*3.3:PSET(X,172-B):PLAY"T255A":PRESET(X,172-B):X=X+Q:NEXT:PSET(X,172-B)
122 LINE(0,0)-(255,20),PRESET,BF:IFP=1THENB=A*1.6+6ELSEIFP=2ORP=8THENB=A*1.9ELSEC$=" O":GOTO124
123 C$=STR$(B):FORA=1TOLEN(C$):IFMID$(C$,A,1)="0"THENMID$(C$,A,1)="O":NEXTELSENEXT
124 DRAW"BM2,10":GOSUB52:AA$="YOU THREW THE DISCUS"+C$+" METERS":GOSUB155
125 DRAW"BM2,20":IFVAL(C$)>49.99THENAA$="YOU QUALIFIED!!!":GOSUB155ELSEGOTO50
126 GOSUB150
127 PCLS:DRAW"BM100,10S4":AA$="8TH EVENT":GOSUB155:DRAW"BM90,100S12":AA$="POLE":GOSUB155:DRAW"BM80,150":AA$="VAULT":GOSUB155:GOSUB152:GOSUB154:LINE(198,150)-(199,179),PSET,B:LINE(200,175)-(255,179),PSET,B:B=0:P=0
128 POKE178,1:PAINT(201,176),,1:COLOR1:DRAW"BM2,10":AA$="PRESS THE SPACE BAR AS FAST AS YOU":GOSUB155:DRAW"BM2,20":AA$="CAN TO VAULT":GOSUB155:SOUND1,10:FORA=20TO140STEP4:IFP=1THENPUT(A,162)-(A+20,179),G,PSETELSEPUT(A,162)-(A+20,179),H,PSET
129 LINE(A+25,170)-(A+50,170),PSET:P=1-P:NEXT:TIMER=0
130 IFINKEY$=" "THENB=B+1
131 IFTIMER<=50THEN130
132 LINE(A,162)-(A+20,179),PRESET,BF:LINE(A+21,170)-(A+45,170),PRESET:PUT(A+10,140)-(A+30,157),J,PSET:LINE(A+50,179)-(A+25,149),PSET:TIMER=0
133 IFINKEY$=" "THENB=B+1
134 IFTIMER<=50THEN133
135 LINE(A+50,179)-(A+25,149),PRESET:LINE(A+10,140)-(A+30,157),PRESET,BF:LINE(A+50,179)-(A+50,149),PSET:FORP=132TO156:PUT(A+60,P)-(A+80,P+17),M,PSET:NEXT
136 B=B*.2:C$=STR$(B):FORA=1TOLEN(C$):IFMID$(C$,A,1)="0"THENMID$(C$,A,1)="O":NEXTELSENEXT
137 LINE(0,0)-(255,140),PRESET,BF:DRAW"BM2,10":AA$="YOU VAULTED"+C$+" METERS":GOSUB155:IFB>=5THENDRAW"BM2,20":AA$="YOU QUALIFIED!!!":GOSUB155ELSEGOTO50
138 GOSUB150
139 PCLS:DRAW"BM100,10S4":AA$="9TH EVENT":GOSUB155:DRAW"BM70,100S12":AA$="JAVELIN":GOSUB155:DRAW"BM80,150":AA$="THROW":GOSUB155:GOSUB152:POKE&H7FE7,&H24:POKE&H7FE8,&H80
140 GOSUB154:DRAW"BM2,10":AA$="PRESS SPACE BAR TO SPEED UP JAVELIN":GOSUB155
141 PUT(20,162)-(40,179),G,PSET:B=0:TIMER=0
142 IFINKEY$=" "THENB=B+1
143 IFTIMER>=100THEN144ELSE142
144 LINE(20,162)-(40,179),PRESET,BF:LINE(40,170)-(55,170),PSET:FOR A=1TOB*3.4:PLAY"T255AAAAAA":EXEC&H7FE6:NEXT:LINE(40,170)-(55,170),PRESET:LINE(40,170)-(50,180),PSET:LINE(0,0)-(255,40),PRESET,BF
145 C$=STR$(B*3.4):FORA=1TOLEN(C$):IFMID$(C$,A,1)="0"THENMID$(C$,A,1)="O":NEXTELSENEXT
146 DRAW"BM2,10":AA$="YOU THREW THE JAVELIN"+C$+" METERS":GOSUB155:IFB*3.4>90THENDRAW"BM2,20":AA$="YOU QUALIFIED!!!":GOSUB155ELSEGOTO50
147 GOSUB150
148 PCLS:DRAW"BM92,10S4":AA$="1OTH EVENT":GOSUB155:DRAW"BM90,100S12":AA$="15OO":GOSUB155:DRAW"BM70,150":AA$="METERS":GOSUB155:GOSUB152:B=1200:TI=250:GOTO42
149 FORB=1TO50:FORA=1TO100:CLSRND(8):NEXT:PRINT"YOU WON THE DECATHLON!!!!!!!!!!!":PLAY"AGFAFADEEECECEEBBEBBEGFFGDAE":CLS:PRINT"you won the decathlon!!!!!!!!!!!":PLAY"AGAFGADECEFEGDADEDED":NEXT:END
150 DRAW"BM60,140S4":AA$="PRESS 'C' TO CONTINUE":GOSUB155
151 IFINKEY$<>"C"THEN151ELSERETURN
152 DRAW"BM40,190S4":AA$="PRESS ANY KEY TO CONTINUE":GOSUB155
153 IFINKEY$=""THEN153ELSERETURN
154 PCLS:LINE(0,180)-(255,180),PSET:POKE178,2:PAINT(1,181),,1:COLOR1:FORQ=1TO255:PRESET(RND(255),RND(9)+180):NEXT:RETURN
155 'CHAR-GEN FOR ZEROS, PUT O       37 CHARACTER ACROSS             TO START AT MIDDLE, DRAW        AT 0,103
156 FOR XX=1 TO LEN(AA$)
157 IF MID$(AA$,XX,1)=" " THEN DRAW CC$(1):GOTO 171
158 IF ASC(MID$(AA$,XX,1))>64 THEN DRAW CC$(ASC(MID$(AA$,XX,1))-63):GOTO171
159 IF ASC(MID$(AA$,XX,1))>48 AND ASC(MID$(AA$,XX,1))<58 THEN DRAWCC$(ASC(MID$(AA$,XX,1))-21):GOTO 171
160 IF MID$(AA$,XX,1)="/"THEN DRAWCC$(37):GOTO171
161 IF MID$(AA$,XX,1)="?" THEN DRAWCC$(38):GOTO 171
162 IF MID$(AA$,XX,1)="!" THEN DRAWCC$(39):GOTO 171
163 IF MID$(AA$,XX,1)="." THEN DRAW CC$(40):GOTO171
164 IF MID$(AA$,XX,1)=":" THEN DRAW CC$(41):GOTO171
165 IF MID$(AA$,XX,1)=";" THEN DRAWCC$(42):GOTO171
166 IF MID$(AA$,XX,1)="," THEN DRAWCC$(43):GOTO171
167 IF MID$(AA$,XX,1)="'" THEN DRAWCC$(44):GOTO171
168 IF MID$(AA$,XX,1)="-" THEN DRAWCC$(45):GOTO171
169 IF MID$(AA$,XX,1)="+" THEN DRAWCC$(46):GOTO171
170 IF MID$(AA$,XX,1)="=" THEN DRAWCC$(47):GOTO171
171 NEXT:RETURN
172 DATA" ","BM+7,0"
173 DATA"A","U4;E2;F2;D2;NL4;D2;BM+3,0"
174 DATA"B","U6;R3;F1;D1;G1;NL3;F1;D1;G1;L3;BM+7,0"
175 DATA"C","BM+1,-0;H1;U4;E1;R2;F1;BM+0,+4;G1;L2;BM+6,0"
176 DATA"D","U6;R3;F1;D4;G1;L3;BM+7,0"
177 DATA"E","NR4;U3;NR2;U3;R4;BM+3,+6"
178 DATA"F","U3;NR2;U3;R4;BM+3,+6"
179 DATA"G","BM+1,-0;H1;U4;E1;R2;F1;BM+0,+2;NL1;D2;G1;L2;BM+6,0"
180 DATA"H","U3;NU3;R4;NU3;D3;BM+3,0"
181 DATA"I","BM+1,0;R1;NR1;U6;NL1;R1;BM+4,+6"
182 DATA"J","BM+0,-1;F1;R1;E1;U5;NL1;R1;BM+3,6"
183 DATA"K","U3;NU3;R1;NE3;F3;BM+3,0"
184 DATA"L","NU6;R4;U1;BM+3,+1"
185 DATA"M","U6;F2;ND1;E2;D6;BM+3,0"
186 DATA "N","U6;F1;D1;F2;D1;F1;NU6;BM+3,0"
187 DATA"O","BM+1,0;H1;U4;E1;R2;F1;D4;G1;L2;BM+6,0
188 DATA"P","U6;R3;F1;D1;G1;L3;BM+7,3"
189 DATA"Q","BM+1,0;H1;U4;E1;R2;F1;D3;G1;NH1;NF1;G1;L1;BM+6,0
190 DATA"R","U6;R3;F1;D1;G1;L2;NL1;F3;BM+3,0"
191 DATA"S","BM+0,-1;F1;R2;E1;U1;H1;L2;H1;U1;E1;R2;F1;BM+3,+5
192 DATA"T","BM+2,+0;U6;NL2;R2;BM+3,+6
193 DATA"U","BM+0,-1;NU5;F1;R2;E1;U5;BM+3,6
194 DATA"V","BM+0,-6;D2;F1;D1;F1;ND1;E1;U1;E1;U2;BM+3,+6"
195 DATA"W","NU6;E2;NU1;F2;U6;BM+3,6"
196 DATA"X","U1;E4;U1;BM-4,0;D1;F4;D1;BM+3,0"
197 DATA"Y","BM+0,-6;D2;F2;ND2;E2;U2;BM+3,6"
198 DATA"Z","NR4;U1;E4;U1;L4;BM+7,6"
199 DATA"1","BM+1,0;R1;NR1;U6;G1;BM+6,+5"
200 DATA"2","NR4;U1;E1;R1;E2;U1;H1;L2;G1;BM+7,+5"
201 DATA"3","BM+0,-1;F1;R2;E1;H2;E2;H1;L3;BM+7,6"
202 DATA"4","BM+3,0;U2;NR1;L3;U1;E3;D3;BM+4,3"
203 DATA"5","BM+0,-1;F1;R2;E1;U2;H1;L3;U2;R4;BM+3,+6"
204 DATA"6","BM+4,-5;H1;L2;G1;D4;F1;R2;E1;U1;H1;L3;BM+7,+3"
205 DATA"7","U1;E4;U1;L4;BM+7,+6"
206 DATA"8","BM+1,-0;H1;U1;E1;H1;U1;E1;R2;F1;D1;G1;NL2;F1;D1;G1;L2;BM+6,0"
207 DATA"9","BM+0,-1;F1;R2;E1;U4;H1;L2;G1;D1;F1;R2;BM+4,+3"
208 DATA"/","U1;E4;U1;BM+3,6"
209 DATA"?","BM+0,-5;E1;R2;F1;D1;G2;BM+0,+1;D1;BM+5,+0"
210 DATA"!","BM+2,+1;U1;BM+0,-2;U5;BM+5,7"
211 DATA".","BM+2,0;U1;BM+5,+1"
212 DATA":","BM+2,-1;U1;BM+0,-2;U1;BM+5,+5"
213 DATA";","BM+1,0;E1;BM+0,-1;U1;BM+5,+4"
214 DATA",","BM+2,0;NU1;G1;BM+6,-1"
215 DATA"'","BM+1,-5;E2;BM+4,+7"
216 DATA"-","BM+0,-3;R4;BM+3,+3"
217 DATA"+","BM+2,-1;U2;NU2;NL2;R2;BM+3,+3"
218 DATA"=","BM+1,-2;R3;BM-3,-2;R3;BM+4,+4"
219 DATA8E,23,0,A6,84,10,8E,00,1F,E6,01,E7,80,31,3F,26,F8,A7,80,8C,26,00,26,EB,39